<%@ Language=VBScript %>
<%
Option Explicit
Response.Expires = 0
On Error Resume Next

'Kein Resultat

'Default, nur vorwärts scrollbar, nicht änderbar, Änderungen anderer User nicht sichtbar
Const adOpenForwardOnly = 0 'Default

'Änderbar, vorwärts- und rückwärts scrollbar, Änderungen anderer User nicht sichtbar
Const adOpenKeyset = 1

'Änderbar, vorwärts- und rückwärts scrollbar, Änderungen anderer User sichtbar
'Dieser Cursor funktioniert nicht mit allen Datenbanken
Const adOpenDynamic = 2

'Nicht änderbar, vorwärts- und rückwärts scrollbar, Änderungen anderer User nicht sichtbar
Const adOpenStatic = 3

'---- LockTypeEnum Values ----
'Nicht änderbar
Const adLockReadOnly = 1 'Default

'Records werden bereits beim Einlesen gesperrt
Const adLockPessimistic = 2

'Records werden nur beim Aufdatieren gesperrt
Const adLockOptimistic = 3

'Records werden nur beim Batch-Update gesperrt
Const adLockBatchOptimistic = 4

Dim objcon, objrspersonen, strsqlinsert, strsqlselpersonen


'*****************************************************************
'Anfang <html>
%>
<!--#include virtual="asppages/silvi/_include/preheader.inc" -->
<html>
  <head>
    <title>ASP Datenbankanbindung: Auslesen und Einfügen von Datensätzen</title>
<!--#include virtual="asppages/silvi/_include/header.inc" -->
  </head>
<body>
<%
'*****************************************************************
'Code innerhalb der HTML-Seite

Set objcon = Server.CreateObject("ADODB.Connection")
objcon.Open "DSN=dsnpersonen"


'Select
strsqlselpersonen = "SELECT * FROM tblpersonen "
Set objrspersonen = Server.CreateObject("ADODB.Recordset")
objrspersonen.Open strsqlselpersonen, objcon, adOpenKeyset, adLockOptimistic

Do While Not objrspersonen.EOF 
  Response.Write(objrspersonen("vorname") & " " & objrspersonen("nachname") & "<br />" & vbcrlf)
  objrspersonen.MoveNext 
Loop
Response.Write("<p />" & vbCrLf)

'Einfügen mit Addnew
objrspersonen.AddNew 
objrspersonen("vorname") = "Hans"
objrspersonen("nachname") = "Müller"
objrspersonen("jahrgang") = 1927
objrspersonen.Update 

'Mit diesem Verfahren erhält man sogar 
'den eindeutigen Schlüssel zurück
Response.Write("<p>personennr: " & objrspersonen("personennr") & " " & _
  objrspersonen("vorname") & " " & objrspersonen("nachname") & "</p>" & vbCrLf)

'Einfügen mit Execute und SQL-Insert
strsqlinsert = "INSERT INTO tblpersonen (vorname, nachname, jahrgang) " & _
  "VALUES ('Peter', 'Meier', 1972) "
objcon.Execute (strsqlinsert)

'wieder einlesen und anzeigen
Response.Write("<br/>" & vbcrlf)

objrspersonen.Close
Set objrspersonen = Nothing
Set objrspersonen = Server.CreateObject("ADODB.Recordset")
objrspersonen.Open strsqlselpersonen, objcon, _
  adOpenKeyset, adLockOptimistic
objrspersonen.MoveFirst 

'Der mit INSERT angefügte Datensatz wird nicht angezeigt
'auch nicht nach Close und Open!!
'erst wenn objrspersonen = Nothing gesetzt und wieder neu
'erzeugt wird, erscheint auch dieser Datensatz
Do While not objrspersonen.EOF 
  Response.Write(objrspersonen("vorname") & " " & _
    objrspersonen("nachname") & "<br />" & vbcrlf)
  objrspersonen.MoveNext 
Loop
Response.Write("<p />" & vbCrLf)
%>
<!--#include file="../_include/inchtmlnachspann.asp" -->
</body>
</html>

Letzter Update: 26.12.2021 16:48

Zurück zur Liste mit ASP-Beispielen auf  www.ecotronics.ch