rothen ecotronics Bern: ASP-Skript "SWP-Einfï¿½hrung ASP 2: Bestï¿½tigung des Updates"

<%@ Language=VBScript %>
<%
Response.Expires = 0

'Kein Resultat

If Len(Request.Form("fldnachname")) < 1 _
  or Len(Request.Form("fldvorname")) < 1 _
  or Len(Request.Form("fldjahrgang")) < 4 _
  or Not IsNumeric(Request.Form("fldjahrgang")) _
  or Not IsNumeric(Request.Form("fldpersonennr")) Then

  Response.Redirect "uebung09b_updateform.asp"
End If
%>
<html>
  <head>
    <meta http-equiv="Content-Type" content="text/html; charset=windows-1252" />
    <title>SWP-Einführung ASP 2: Bestätigung des Updates</title>
  </head>
<body>
<%
'*****************************************************************
'Code innerhalb der HTML-Seite
Dim objcon, objrs, strsql
Set objcon = Server.CreateObject("ADODB.Connection")
'ODBC on the fly
objcon.Open "DRIVER={Microsoft Access Driver (*.mdb)}; " & _
  "DBQ=" & Server.MapPath("/asppages/silvi/db/dbpersonen2000.mdb")

Set objrs = Server.CreateObject("ADODB.Recordset")
'Trick: Mit Primärschlüssel in verstecktem Feld Datensatz finden
strsql = "SELECT * FROM tblpersonen WHERE personennr = " & _
  Request.Form("fldpersonennr")
'Recordset für Änderungen öffnen
objrs.Open strsql, objcon, 1, 3

if objrs.RecordCount = 1 Then
  objrs("nachname")= Request.Form("fldnachname")
  objrs("vorname")= Request.Form("fldvorname")
  objrs("jahrgang") = Request.Form("fldjahrgang")
  objrs.Update
End If

Response.Write("<p>Sie haben folgenden Datensatz geändert</p><p>" & vbCrLf)
Response.Write("Nr " & objrs("personennr") & ", " & _
  objrs("nachname") & ", " & _
  objrs("vorname") & ", " & _
  objrs("jahrgang") & "</p>" & vbCrLf)

objrs.Close
Set objrs = Nothing

objcon.Close
Set objcon = Nothing
%>

</body>
</html>

Letzter Update: 26.12.2021 16:48

Zurück zur Liste mit ASP-Übungen auf www.ecotronics.ch