rothen ecotronics Bern: ASP-Skript "ASP Datenbankanbindung: Artikel aus DB anzeigen"

<%@ Language=VBScript %>
<%
Option Explicit
Response.Expires = 0
'On Error Resume Next

'*****************************************************************
'Variablendeklarationen
Const adOpenKeyset = 1
Const adLockOptimistic = 3

Dim objcon
Dim objfield
Dim objrs
Dim strsqlselect

'*****************************************************************
'Variableninitialisierung
set objcon = Server.CreateObject("ADODB.Connection")
set objrs = Server.CreateObject("ADODB.Recordset")

'*****************************************************************
'Lokale Prozeduren und Funktionen

'*****************************************************************
'Anfang Code

'*****************************************************************
'Anfang <html>
%>
<html>
  <head>
    <meta http-equiv="Content-Type" content="text/html; charset=windows-1252" />
    <title>ASP Datenbankanbindung: Artikel aus DB anzeigen</title>
    <meta name="description" content="" />
    <meta name="keywords" content="" />
  </head>
<body>
<%
'*****************************************************************
'Code innerhalb der HTML-Seite
if Request.Form("frmfldkategorienr") <> "" then
  'mit ODBC
  'objcon.Open "DSN=dsnartikel"
  'ohne ODBC
  objcon.Open "DRIVER={Microsoft Access Driver (*.mdb)}; " & _
    "DBQ=" & server.MapPath("/asppages/silvi/db/dbartikel2000.mdb")

  strsqlselect = "SELECT tblkategorien.Kategoriename, tblartikel.Artikelname, "&_
    "tblartikel.Einzelpreis, tblartikel.Lagerbestand "&_
    "FROM tblkategorien, tblartikel "&_
    "WHERE tblkategorien.Kategorienr=" & Request.Form("frmfldkategorienr")& _
    " AND tblartikel.Auslaufartikel=0 " &_
    "AND tblkategorien.Kategorienr = tblartikel.Kategorienr "&_
    "ORDER BY tblartikel.Artikelname"
  objrs.Open strsqlselect, objcon, adOpenKeyset, adLockOptimistic

  Response.Write("<h1>" & objrs("kategoriename") & "</h1>" & vbCrLf & _
    "<table>" & vbCrLf)
  'Tabellenkopf
  for each objfield in objrs.fields
    if LCase(objfield.name) <> "kategoriename" then
      Response.Write("    <td><b>" & vbCrLf)
      Response.Write("      " & objfield.name & vbCrLf)
      Response.Write("    </b></td>" & vbCrLf)
    end if
  next
  Do while not objrs.EOF
    Response.Write("  <tr>" & vbCrLf)
    for each objfield in objrs.fields
      if LCase(objfield.name) <> "kategoriename" then
        Response.Write("    <td>" & vbCrLf)
        if objfield.type = 6 then
          Response.Write("      " & formatcurrency(objfield.value,2) & vbCrLf)
        else
          Response.Write("      " & objfield.value & vbCrLf)
        end if
        Response.Write("    </td>" & vbCrLf)
      end if
    next
    Response.Write("  </tr>" & vbCrLf)
    objrs.MoveNext
  Loop
  Response.Write("</table>" & vbCrLf)
else 'Request.Form("frmfldkategorienr") <> ""
  Response.Write("Keine Artikel gefunden<br />" & vbCrLf)
end if 'else Request.Form("frmfldkategorienr") <> ""
%>

</body>
</html>

Demo: uebungen/uebung6_8artkat2.asp

Letzter Update: 26.12.2021 16:48

Zurück zur Liste mit ASP-Übungen auf www.ecotronics.ch