rothen ecotronics Bern: ASP-Skript "ASP Schlussprojekt: Formular Kursbeurteilung mit DB-Anbindung"

<%@ Language=VBScript %>
<%
Option Explicit
Response.Expires = 0
On Error Resume Next

'Kein Resultat

'Ja/Nein-Felder müssen mit 1 für Ja und 0 für Nein abgefüllt werden
'In dieser Lösung sind Formular und Bestätigung auf derselben Seite

'*****************************************************************
'Variablendeklarationen
Const adOpenKeyset = 1
Const adLockOptimistic = 3

Dim blnfirmenkunde
Dim intfragebogennr
Dim objcon
Dim objfield
Dim objrs
Dim strfield
Dim strsqlselect

'*****************************************************************
'Anfang Code
if Request.Form("btnsubmit") = "Abschicken" then
  Set objcon = Server.CreateObject("ADODB.Connection")
  Set objrs =  Server.CreateObject("ADODB.Recordset")
  'mit ODBC
  'objcon.Open "dsn=dsnfragebogen"
  'ohne ODBC
  objcon.Open "DRIVER={Microsoft Access Driver (*.mdb)}; " & _
    "DBQ=" & server.MapPath("/asppages/silvi/db/dbspfragebogen2000.mdb")

  'Mit einer unmöglichen WHERE-Bedingung wird ein leeres Recordset geholt
  strsqlselect = "SELECT * FROM tblfragebogen WHERE fragebogennr IS NULL"

  objrs.Open strsqlselect, objcon, adOpenKeyset, adLockOptimistic

  objrs.AddNew
  objrs("name") = Request.Form("frmfldname")

  if Request.Form("frmfldfirmenkunde") = "Ja" then
    objrs("firmenkunde") = 1
  else
    objrs("firmenkunde") = 0
  end if

  objrs("gesamteindruckkurs") = Request.Form("frmfldgesamteindruckkurs")
  objrs("katalogziel") = Request.Form("frmfldkatalogziel")

  objrs("katanwender") = 0
  objrs("katinformatiker") = 0
  objrs("katnovell") = 0
  For Each strfield In Request.Form("frmfldpublikationen")
    Select case strfield
      case "katanwender"
        objrs("katanwender") = 1
      case "katinformatiker"
        objrs("katinformatiker") = 1
      case "katnovell"
        objrs("katnovell") = 1
    end select
  Next

  objrs("gefallen") = Request.Form("frmfldgefallen")

  objrs.Update
end if

'*****************************************************************
'Anfang <html>
%>
<html>

<head>
<meta http-equiv="Content-Language" content="de-ch">
<meta http-equiv="Content-Type" content="text/html; charset=windows-1252">
<title>ASP Schlussprojekt: Formular Kursbeurteilung mit DB-Anbindung</title>
</head>

<body>
<%
'Hier werden die Eingaben bestätigt
if Request.Form("btnsubmit") = "Abschicken" then
  Response.Write("<p>Danke für Ihre Eingaben</p>" & vbCrLf)
  For each objfield in objrs.fields
    Response.Write( "<b>" & objfield.name & "</b>: " & objfield.value & "<br />" & vbCrLf)
  next
else
'Das Formular wird nur beim ersten Aufruf der Seite angezeigt
%>
<form method="POST" action="uebung7_sp1.asp">
  <h1>Kursbeurteilung</h1>
  <table border="0">
    <tr>
      <td valign="top">Name</td>
      <td valign="top"><input type="text" name="frmfldname" size="20"></td>
    </tr>
    <tr>
      <td valign="top">Firmenkunde</td>
      <td valign="top"><input type="checkbox" name="frmfldfirmenkunde" value="Ja">Ja</td>
    </tr>
    <tr>
      <td valign="top">Gesamteindruck Kurs</td>
      <td valign="top"><select size="1" name="frmfldgesamteindruckkurs">
          <option value="6">hervorragend</option>
          <option value="5.5">sehr gut</option>
          <option value="5">gut</option>
          <option value="4.5">genügend bis gut</option>
          <option value="4">genügend</option>
          <option value="3">ungenügend</option>
        </select></td>
    </tr>
    <tr>
      <td valign="top">Katalogziel erreicht</td>
      <td valign="top"><input type="radio" value="Ja" name="frmfldkatalogziel">Ja  
        <input type="radio" value="Bedingt" name="frmfldkatalogziel">Bedingt  
        <input type="radio" value="Nein" name="frmfldkatalogziel">Nein</td>
    </tr>
    <tr>
      <td valign="top">Bitte senden Sie mir folgende Publikationen?</td>
      <td valign="top"><select size="3" name="frmfldpublikationen" multiple>
          <option value="katanwender">Katalog PC-Kurse für Anwender</option>
          <option value="katinformatiker">Katalog Seminare für Informatiker</option>
          <option value="katnovell">Katalog Novell-Seminare</option>
        </select></td>
    </tr>
    <tr>
      <td valign="top">Was hat besonders gefallen?</td>
      <td valign="top"><textarea rows="2" name="frmfldgefallen" cols="20"></textarea></td>
    </tr>
  </table>
  <p><input type="submit" value="Abschicken" name="btnsubmit" /><input type="reset" value="Zurücksetzen" name="btnreset" /></p>
</form>
<%
end if
%>

</body>
</html>

Letzter Update: 26.12.2021 16:48

Zurück zur Liste mit ASP-Übungen auf www.ecotronics.ch